home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / pc / LOGIC Apple II 5.25" Library - DOS Part 3 / DOS077A.dsk / CRAPS II.bas < prev    next >
BASIC Source File  |  2012-02-16  |  6KB  |  138 lines
  1. 0  REM                                       C R A P S
  2. 1  REM                               THIS PROGRAM WAS WRITTEN   BY BREK MILLER, AN EIGHTH   GRADER AT CENTRAL JUNIOR    HIGH SCHOOL, CHAMBERSBURG    , PA. 2/19/80.
  3. 2  REM 
  4. 3  REM                            CONTRIBUTED BY RICHARD RUTH KEYSTONE APPLE CORE
  5. 4  REM 
  6. 5  CLEAR :A = 200
  7. 10  GR : HOME : REM   DRAW DICE
  8. 20  COLOR= 15
  9. 30  FOR M = 10 TO 21  STEP 11
  10. 40  FOR N = 0 TO 8: HLIN M,M +8 AT N: NEXT N
  11. 50  NEXT M
  12. 60  COLOR= 1
  13. 70  HLIN 10,18 AT 0: HLIN 21,29 AT 0: HLIN 10,18 AT 8: HLIN 21,29 AT 8
  14. 80  VLIN 0,8 AT 10: VLIN 0,8 AT 18: VLIN 0,8 AT 21: VLIN 0,8 AT 29
  15. 90  FOR K = 0 TO 30: REM   START ROLL
  16. 150  IF K = 0  THEN 170
  17. 160  COLOR= 0: HLIN 10,29 AT K -1
  18. 170  COLOR= 1: HLIN 10,18 AT K: HLIN 21,29 AT K
  19. 210  COLOR= 15: HLIN 11,17 AT K +7: HLIN 22,28 AT K +7
  20. 220  COLOR= 1: HLIN 10,18 AT K +8: HLIN 21,29 AT K +8
  21. 230  NEXT K
  22. 240  PLOT 14,34: PLOT 25,34: REM  PRINT CRAPS
  23. 250  VLIN 13,17 AT 8: HLIN 8,11 AT 13: HLIN 8,11 AT 17
  24. 260  VLIN 13,17 AT 13: HLIN 13,16 AT 13: HLIN 13,16 AT 15: PLOT 16,14: PLOT 15,16: PLOT 16,17
  25. 270  VLIN 14,17 AT 18: VLIN 14,17 AT 21: PLOT 19,13: PLOT 20,13: PLOT 19,16: PLOT 20,16
  26. 280  VLIN 13,17 AT 23: HLIN 23,26 AT 13: HLIN 23,26 AT 15: PLOT 26,14
  27. 290  HLIN 28,31 AT 13: HLIN 28,31 AT 15: HLIN 28,31 AT 17: PLOT 28,14: PLOT 31,16
  28. 300  PRINT : PRINT  TAB( 10);"WRITTEN BY BREK MILLER": REM  CREDITS
  29. 310  PRINT : PRINT  TAB( 6);"WITH ASSISTANCE FROM MR. RUTH"
  30. 320  FOR N = 1 TO 4000: NEXT N: REM  PAUSE 
  31. 330  REM   INSTRUCTIONS
  32. 340  TEXT : HOME 
  33. 350  INPUT "DO YOU WANT TO SEE THE INSTRUCTIONS?";A$
  34. 360  IF  LEFT$(A$,1) = "Y"  THEN 390
  35. 370  IF  LEFT$(A$,1) = "N"  THEN 530
  36. 380  PRINT : PRINT "ANSWER YES OR NO": PRINT : GOTO 350
  37. 390  HOME 
  38. 400  PRINT  TAB( 17);"*******"
  39. 410  PRINT  TAB( 17);"*";: INVERSE : PRINT "CRAPS";: NORMAL : PRINT "*"
  40. 420  PRINT  TAB( 17);"*******"
  41. 430  PRINT  TAB( 11);"YOU START WITH $200,"
  42. 435  PRINT  TAB( 5);"BET WHAT YOU WANT ON EACH TURN."
  43. 440  PRINT : PRINT "*****EACH TURN IS PLAYED AS FOLLOWS*****"
  44. 445  PRINT : PRINT "     ON THE FIRST ROLL IF YOU GET:"
  45. 450  PRINT : PRINT  TAB( 8);"7 OR 11 - (NATURAL) YOU WIN"
  46. 455  PRINT  TAB( 5);"2,3, OR 12 - (CRAPS) YOU LOSE"
  47. 460  PRINT : PRINT  TAB( 5);"ANYTHING ELSE BECOMES YOUR POINT"
  48. 470  PRINT : PRINT  TAB( 10);"THEN ROLL TILL YOU GET:"
  49. 480  PRINT : PRINT  TAB( 11);"YOUR POINT - YOU WIN"
  50. 490  PRINT  TAB( 16);"SEVEN - YOU LOSE!"
  51. 500  PRINT "****************************************"
  52. 510  PRINT "  TO START A NEW GAME ENTER 0 AS A BET"
  53. 520  PRINT  TAB( 6);"PRESS SPACE BAR TO CONTINUE...";: GET A$
  54. 530  CLEAR :A = 200: REM   RESET ALL VARIABLES FOR NEW GAME
  55. 540  REM  BETTING PAGE
  56. 550  TEXT : HOME 
  57. 560  IF W >1  THEN  PRINT "YOU'VE WON THE LAST ";W;" GAMES IN A ROW"
  58. 570  IF L >1  THEN  PRINT "YOU'VE LOST THE LAST ";L;" GAMES IN A ROW"
  59. 580  PRINT : PRINT "YOU HAVE $";A
  60. 590  INPUT "HOW MUCH DO YOU WANT TO BET ?";B
  61. 600  IF (B < = A)  THEN 620
  62. 610  PRINT : PRINT "THINK AGAIN, YOU ONLY HAVE $";A: GOTO 590
  63. 620  IF B = 0  THEN 340: REM   IF B=0 START A NEWE GAME
  64. 630  REM  DRAWING DICE
  65. 640  GR : HOME 
  66. 650  COLOR= 12: REM   FILL SCREEN W/ GREEN
  67. 660  FOR N = 0 TO 39: HLIN 0,39 AT N: NEXT N
  68. 670  COLOR= 15: REM   WHITE SQUARES
  69. 680  FOR N = 16 TO 24: HLIN 10,29 AT N: NEXT N
  70. 690  COLOR= 1: HLIN 10,29 AT 16: HLIN 10,29 AT 24: VLIN 16,24 AT 10: VLIN 16,24 AT 18: VLIN 16,24 AT 21: VLIN 16,24 AT 29
  71. 700  COLOR= 12: VLIN 16,24 AT 19: VLIN 16,24 AT 20
  72. 710  COLOR= 1: PLOT 14,20: PLOT 25,20
  73. 720  REM   THE PLAY
  74. 730  PRINT "PRESS SPACE BAR TO ROLL": GET A$: HOME 
  75. 740  GOSUB 1020: REM   FIRST ROLL
  76. 750 Z = X +Y: IF (Z = 7)  OR (Z = 11)  THEN 780: REM    CK FOR N            ATURAL 
  77. 760  IF (Z = 2)  OR (Z = 3)  OR (Z = 12)  THEN 790: REM   CK FOR CRAPS
  78. 770  GOTO 800
  79. 780  PRINT "NATURAL, YOU WIN !": GOTO 870
  80. 790  PRINT "CRAPS, YOU LOSE.": GOTO 890
  81. 800  PRINT "YOUR POINT IS ";Z: PRINT "<CTRL-G>"
  82. 810  GET A$: GOSUB 1020: REM   SECOND ROLL
  83. 820 V = X +Y: IF V = Z  THEN 850: REM    CK FOR POINT 
  84. 830  IF V = 7  THEN 860: REM    CK  FOR 7
  85. 840  GOTO 810: REM   RE-ROLL
  86. 850  PRINT : PRINT "YOUR POINT, YOU WIN !": GOTO 870
  87. 860  PRINT : PRINT "7, YOU LOSE.": GOTO 890
  88. 870  PRINT "<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>":A = A +B:L = 0:W = W +1
  89. 880  FOR N = 1 TO 2000: NEXT N: GOTO 540
  90. 890  FOR N = 1 TO 10:S =  PEEK( -16336): NEXT N
  91. 900 A = A -B:W = 0:L = L +1
  92. 910  FOR N = 1 TO 2000: NEXT N
  93. 920  IF A >0  THEN 540: REM   CK IF BROKE
  94. 930  REM   BROKE PAGE
  95. 940  TEXT : HOME 
  96. 950  PRINT  TAB( 14);"YOU ARE BROKE"
  97. 960  INPUT "  DO YOU WANT TO PLAY ANOTHER GAME?";A$
  98. 970  IF  LEFT$(A$,1) = "Y"  THEN 330
  99. 980  IF  LEFT$(A$,1) = "N"  THEN 995
  100. 990  PRINT : PRINT "ANSWER YES OR NO": PRINT : GOTO 960
  101. 995  HOME 
  102. 1000  PRINT  TAB( 16);"APPLE ]["
  103. 1010  END 
  104. 1020  REM  SUBPROGRAM ROLLING THE DICE
  105. 1030  FOR R = 1 TO 5
  106. 1035  REM  ERASE OLD POINTS
  107. 1040  COLOR= 15: VLIN 18,22 AT 12: VLIN 18,22 AT 16: VLIN 18,22 AT 23: VLIN 18,22 AT 27: PLOT 14,20: PLOT 25,20
  108. 1050  COLOR= 1
  109. 1060 X =  INT( RND(1) *6) +1: REM   PICK NEW ROLL
  110. 1070 Y =  INT( RND(1) *6) +1
  111. 1075  REM  PLOT LEFT PIPS
  112. 1080  IF X = 1  THEN 1090
  113. 1081  IF X = 2  THEN 1100
  114. 1082  IF X = 3  THEN 1110
  115. 1083  IF X = 4  THEN 1120
  116. 1084  IF X = 5  THEN 1130
  117. 1085  GOTO 1140
  118. 1090  PLOT 14,20: GOTO 1150
  119. 1100  PLOT 16,18: PLOT 12,22: GOTO 1150
  120. 1110  PLOT 16,18: PLOT 14,20: PLOT 12,22: GOTO 1150
  121. 1120  PLOT 12,18: PLOT 16,18: PLOT 12,22: PLOT 16,22: GOTO 1150
  122. 1130  PLOT 12,18: PLOT 16,18: PLOT 12,22: PLOT 16,22: PLOT 14,20: GOTO 1150
  123. 1140  PLOT 12,18: PLOT 12,20: PLOT 12,22: PLOT 16,18: PLOT 16,20: PLOT 16,22
  124. 1145  REM  PLOT RIGHT PIPS
  125. 1150  IF Y = 1  THEN 1160
  126. 1151  IF Y = 2  THEN 1170
  127. 1152  IF Y = 3  THEN 1180
  128. 1153  IF Y = 4  THEN 1190
  129. 1154  IF Y = 5  THEN 1200
  130. 1155  GOTO 1210
  131. 1160  PLOT 25,20: GOTO 1220
  132. 1170  PLOT 27,18: PLOT 23,22: GOTO 1220
  133. 1180  PLOT 27,18: PLOT 25,20: PLOT 23,22: GOTO 1220
  134. 1190  PLOT 23,18: PLOT 27,18: PLOT 23,22: PLOT 27,22: GOTO 1220
  135. 1200  PLOT 23,18: PLOT 27,18: PLOT 23,22: PLOT 27,22: PLOT 25,20: GOTO 1220
  136. 1210  PLOT 23,18: PLOT 23,20: PLOT 23,22: PLOT 27,18: PLOT 27,20: PLOT 27,22
  137. 1220  NEXT R
  138. 1230  RETURN